extproc perl -S -w

# This script converts files in subdirectories too, so run it as
#    convert_configure
#
# When the converted script runs, it expects that /tmp dir is
# available (so we create it).
#
# run the result like this:
#    sh configure

# Some frequent manual intervention:
# a) Some makefiles hardwire SHELL = /bin/sh ==> change to: sh
#	Most of the time one can put SHELL = @SHELL@ into Makefile.in
#
# b) Some configure scripts recognize that exe files terminate on .exe
#    You need to give this script -no-zexe option...  [autodetected with newer
#    configure.]
#
# c) to disable autodetection, use -zexe option 

use strict;
use File::Find 'find';
use File::Copy 'copy';

my ($no_zexe, $zexe, $overwrite, $omf) = ('') x 4;

for (1..20) {
  shift, $no_zexe = 1 if @ARGV and $ARGV[0] eq '-no-zexe';
  shift, $zexe = 1 if @ARGV and $ARGV[0]    eq '-zexe';
  shift, $omf = 1 if @ARGV and $ARGV[0]    eq '-zomf';
  shift, $overwrite = 1 if @ARGV and $ARGV[0]    eq '-overwrite';
}

die "Can't have both -no-zexe and -zexe." if $no_zexe and $zexe;

my $VERSION = '20030101';

die <<EOD if @ARGV;
  usage (version $VERSION):
	$0 [-no-zexe|-zexe] [-zomf] [-overwrite]
EOD

unless ($zexe or $no_zexe or not -f 'configure') {
  # autodetect
  my ($no_exeext, $cv_exeext);
  open CONF, 'configure' or die;
  while (<CONF>) {
    $no_exeext = 1 if /^ac_exeext=\s/;		# overwritten ac_exeext
    $cv_exeext = 1 if /ac_cv_exeext=/;	# autodetected ac_exeext (but late)
  }
  close CONF;
  if ($cv_exeext and not $no_exeext) {
    $no_zexe = 1;
    warn <<EOW;
Autodetected newer configure; assuming -no_zexe.
  Give option -zexe to disable.
EOW
  } else {
    my $ee   = $no_exeext ? '' : ' not';
    my $cvee = $cv_exeext ? '' : ' not';
    warn <<EOW;
Autodetecting newer configure; switch off of ac_exeext$ee found;
  detection of ac_cv_exeext$cvee found; assuming -zexe.
    Give option -no-zexe to disable.
EOW
  }
}

mkdir '/tmp', 0777 unless -d '/tmp';
find \&worker, '.';
print STDERR <<EOM ;

Run configure in toplevel directory as
	sh configure

(add extra arguments as required per --help option).  Set do_OMF and/or
GCC_OMF_OPT in environment to force/disable the OMF build and modify (sane
default for) additional options in OMF mode.  Set X11_ROOT_OPT if needed
during configure (the default is sane).

The OMF build has wrong detection of missing libraries; thus one may get
many (harmless) warnings L4051 about missing libraries during linking.

OMF build would not work with some obsolete configure scripts.

EOM

sub worker {
  return unless /^config(ure|\.guess|\.sub)$/ and not -d;
  print STDERR "converting $File::Find::dir/$_ ...\n";
  my $from = "$_-pre-os2";
  if (-f $from and not $overwrite) {
    print STDERR "  ... Existing $File::Find::dir/$from detected.  Using the previous original\n";
  } else {
    print STDERR "  ... Creating backup $File::Find::dir/$from.\n";
    copy $_, $from or die "Error creating backup $File::Find::dir/$from: $!";
  }
  open IN, $from or die "Cannot open $from in $File::Find::dir/ for read: $!";
  chmod 0666, $_;
  open OUT, ">$_"
    or die "Cannot open $_ in $File::Find::dir/ for write: $!";
  select OUT;
  { local $_ = $_;
    do_configure() if /configure/;
    do_guess() if /\.(guess|sub)/;
  }
  close IN or die "Cannot close $from in $File::Find::dir/ for read: $!";
  close OUT or die "Cannot close $_ in $File::Find::dir/ for write: $!";
}

sub do_configure {
  print <<EOF;
extproc sh

# Call as
#	sh configure

EOF

  my $Zexe = $no_zexe ? '' : '-Zexe';
  print <<EOF;
do_OMF=\${do_OMF-"$omf"}
if test "\$do_OMF" = 0; then do_OMF=""; fi

if test -n "\$do_OMF"; then
  # Assume -Zcrtdll...
  GCC_OMF_OPT=\${GCC_OMF_OPT-"-Zomf -Zcrtdll -Zstack 8192"}
  FFLAGS=\${FFLAGS-"\$GCC_OMF_OPT"}
  libext=lib
  # Use quite large size of chunk; the library can get slightly larger,
  # but this supports libraries up to 4M large
  AR="emxomfar -p128"
  export AR
  NM=emxomfnm			# Get one!
  export NM
fi

if test -n "\$X11ROOT" -a -d "\$X11ROOT/XFree86/include"; then
  X11_ROOT_OPT=\${X11_ROOT_OPT-"-I\$X11ROOT/XFree86/include -L\$X11ROOT/XFree86/lib"}
fi

# Make sensible defaults:
CC="gcc $Zexe -Zmt \$GCC_OMF_OPT \$X11_ROOT_OPT"
export CC
actual_CC="gcc -Zmt \$GCC_OMF_OPT \$X11_ROOT_OPT"
CXX="gcc $Zexe -Zmt \$GCC_OMF_OPT \$X11_ROOT_OPT"
export CXX
#GCCOPT="\$GCCOPT -Zexe"
#export GCCOPT
EOF

  print <<EOF if $no_zexe;
# Make sensible defaults:
ac_exeext=.exe
# used by libtool (is it propagating?)
exeext=.exe
EOF

  print <<EOF;
CONFIG_SHELL=sh
export CONFIG_SHELL
actual_LN_S=cp

# Optimization (GNU make 3.74 cannot be loaded :-():
emxload -m 30 sh.exe ls.exe tr.exe id.exe sed.exe # make.exe 
emxload -m 30 grep.exe egrep.exe fgrep.exe cat.exe rm.exe mv.exe cp.exe
emxload -m 30 uniq.exe basename.exe sort.exe awk.exe

function test_x_exe {
  test -f "\$1" || test -f "\$1.exe"
}

EOF

  my ($checking_path,$checking_install,$varname,$subst,$rm_exit);
  $checking_path = 0;

  while (<IN>) {
    # s/^(\s*)exit 1$/$1$rm_exit/ if defined $rm_exit;
    # undef $rm_exit if $rm_exit;

    if (/for\s+(\w+)\s+in\s*\$(PATH|ac_dummy)\s*;/) {
      $checking_path = 1;
      $varname = $1;
      $subst = <<EOS
$varname="`echo -E \\"\$$varname\\" | tr \\\\\\\\\\\\\\\\ / `"
EOS
    } 
    if (/if\s+test\s+-z\s+\"\$INSTALL\"/) {
      $checking_install = 1;
    } 
    $checking_install = $checking_path = 0 if /^\s*done\s*$/;
    # We want to create an extra line like this one:
  #   ac_dir="`echo -E \"$ac_dir\" | tr \\\\\\\\ / `"
    s{^((\s*)if\s+test)\s*-f\s*(\$$varname/\S+)\s*;}
     {$2$subst$1 -f $3 -o -f $3.exe ;}
        if $checking_path;	# Checking for executables

    # change |/usr/sbin/*| to |/usr/sbin/*|?:[\\/]os2[\\/]install[\\/]*|
    # in the list of things to skip (with both cases)
    s{\|\s*/usr/sbin/\*\s*\|}
     {|/usr/sbin/*|?:[\\\\/]os2[\\\\/]install[\\\\/]*|?:[\\\\/]OS2[\\\\/]INSTALL[\\\\/]*|}
        if $checking_install;	# Do not accept d:/os2/install/install.exe

    # s/^(host|build)=NONE$/$1=x86-emx-os2/;	# Make default host/build
    s/"\$\{IFS}:"$/"\${IFS};"/;	# Fix IFS line
    s/\bIFS=\":\"$/IFS=";"/;	# Fix another IFS line

    # Do not fix exe-exists test finished at $ac_exeext or some such
    s/\btest\s+-s\s+conftest\b(?!\.|\${?ac\w*_exeext)/test -f conftest/g; # Fix exe test
    s/\btest\s+-s\s+conftest(?=\${?ac\w*_exeext)/test -f conftest/g unless $no_zexe;

    # This one is needed for curses:
    # s/^\s*host=`.*\$ac_config_sub \$host_alias`/$&\nif test -z "\$host"; then host=\$host_alias; fi/;

    # These are needed for ssh in a subdir MP:
    #s/^(host_alias)=NOHOST$/$1=x86-emx-os2/;
    # $rm_exit = 'result="$host_alias"' if /Unrecognized (host|target) system name/;
    s/^(\s*hard_link)=ln$/$1=cp/;
    s/^(\s*symbolic_link)='ln -s'$/$1=cp/;
    # allow for $progname to be terminated in . (pdksh bug)
# progname=$0	
    s,(^progname=\$0\s+$),$1\nprogname=`echo \${progname} | sed 's/\\.\$//'`\n,;

#    s/^\s*if\s+hostalias=`\$\{\w+\}`/$&\nif test -z "\$host"; then host=\$host_alias; fi/;
    s,(?<!{CONFIG_SHELL-)/bin/sh(?![/\w]),sh,g;
    s,^(\s*/usr/sbin/sendmail\s*)\\$,$1 "`whence sendmail | tr '\\\\\\\\' / `" \\,;
    s,(^\s*ac_cv_prog_LN_S)="ln\s+-s"$,$1="\${actual_LN_S:-ln -s}",;
    s,(^\s*ac_cv_prog_LN_S)="ln"$,$1="\${actual_LN_S:-ln}",;
    s,LTCC="\$CC"\s+CC="\$CC",LTCC="\${actual_CC:-\$CC}" CC="\${actual_CC:-\$CC}",; # Part of libtool startup
    s,^as_executable_p="test\s+-f"$,as_executable_p=test_x_exe,;
    # this is output to config.status:
    s,ln\s+\$srcdir/\$ac_source\s+\$ac_dest,cp -f \$srcdir/\$ac_source \$ac_dest,;

    #   When see:	test -z "$as_dir" && as_dir=.
    #   Add:		as_dir=`print -r "$as_dir" | tr '\\\\' / `
    s,^(\s*)(test\s+-z\s+"\$as_dir"\s+&&\s+as_dir=\.)\s*$,$1$2\n${1}as_dir=`print -r "\$as_dir" | tr '\\\\\\\\' / `\n,;

    # These are needed for -Zomf build
    s/^libext=a$/libext=\${libext-a}/;

    #     test ! -f ${_sed} && break   => $as_executable_p ${_sed} || break
    s/^\s*test\s*!\s*-f\s*\$\{_sed\}\s*&&/\$as_executable_p \${_sed} ||/;

    # libtool produces .def files with SINGLE NONSHARED!
    s/^(\s*archive_cmds=.*)\bSINGLE\s+NONSHARED\b/${1}MULTIPLE NONSHARED/;
    print;
  }
}

sub do_guess {
  local $/;
  my $in = <IN>;
  $in =~ s/(^#!.*\n)/$1echo i386-pc-os2-emx; exit 0;\n\n/;
  print $in;
}

__END__

Changes:	98/11 : support check for executables in ncurses.
		99/2  : support INSTALL, 
			new IFS=':' style
		99/11 : find sendmail
		00/01 : export CONFIG_SHELL
		00/10 : new syntax for host=`...` line, build= defined
			new option -no-zexe (needed?).
			Preload useful commands.
		00/11 : New usage: no name should be given, will create
			configure and configure.guess automatically in all subdirectories.
			support callin configure.cmd in subdirectories.
		01/06 : chmod to allow read-only files.
		02/01 : Set LN_S to a sane value.
			When starting libtool, give the -Zexe-less $CC
		03/01 : -zexe option to disable autodetection;
			autodetect -no-zexe with newer configure;
			sets ac_exeext;
			sets as_executable_p;
			replace ln in config.guess;
			fix the REx for /usr/sbin/* for disabling OS/2 install;
			allow libext to be predefined
			convert \ to / in autoconf 2.57 too
		03/09 : new bug in Configure (2.57): ${_sed} without .exe...
			new option -zomf sets default
			easy to edit ./configure for OMF... (better have emxomfnm)
			Populate -I and -L basing on $X11ROOT
		04/02 : Add -Zomf etc to FFLAGS if needed
			Slightly better docs for DO_OMF
Logic:
	a) modify config.guess and config.sub (not needed with newer
		versions - starting from Dec 00) to accept os2;
	b) Inside loops which check $dir in $PATH, convert \ to / in $dir,
	   and check for $dir/foo.exe too;
	   [Avoid conversion by converting \ to / in $PATH at the start???]
	c) When setting $INSTALL, skip directory ?:[\\/]os2[\\/]install[\\/]*
	   (done by changing |/usr/sbin/*| to
	    |/usr/sbin/*|?:[\\/]os2[\\/]install[\\/]*|
	    in the list of things to skip (with both upper/lower cases)).
	d) Change IFS for splitting of $PATH:  "$\{IFS}:" to "\${IFS};"
	   and IFS=":" to IFS=";".
	e) Change check the tests for existence of linked executable:
	   test -s conftest to test -f conftest;
	   [Do test -s conftest$ac_executable_ext instead?]
	f) change hard_link and symbolic_link assignmet to put cp there;
	g) Workaround against a bug in pdksh: $0 may end in a spurious "."
	   (which does not change the file name from the POV of OS, but may
	   break if the script tests $0 for equality)
	h) Substitute sh for /bin/sh [when setting SHELL= and CONFIG_SHELL=,
	   not needed on #! lines].
	i) substitute /usr/sbin/sendmail by the actual path to sendmail.
	j) Changes LN_S to be cp
	k) set as_executable_p to a sane value;
	l) replace ln in config.guess;
	m) allow libext to be predefined;
	n) replace `test -f ${_sed}' by $as_executable_p;
	o) replace broken SINGLE NONSHARED in .def file generation by the correct one
Also:
	1) Ensures that /tmp exists;
	2) Sets CONFIG_SHELL=sh at the start;
	3) Sets CC and CXX to the value appropriate for Makefiles and
	   shell scripts which do not expect the need for .exe. [Optional]
	4) Not fixed: libtool uses $exeext, which is not set.
NOT DONE YET:
	Some build tools (e.g., of Sablot) require cygpath command to be
	present.  It is easy to write emulation so that "cygpath -w file"
	acts as "echo file".  Newer configure autodetects this, so make it
	fail unless run with -w.
		#!/bin/sh
		# This is quite a placeholder
		case "$1" in
		  -w)	shift;;
		  *)	exit 1;;
		esac
		echo "$1"